[vb Easy] Export Some Registry Keys To File

[Dominik]

Can anybody make a small VBscript which will export these registry keys to separate files? Here's how i want it,trasnlated to normal language

---------------------------------------------

export [HKEY_CURRENT_USER\Software\XXXXXXXX]

save it as X:\XXXX\XXX.REG

next

export [HKEY_CURRENT_USER\Software\ZZZZZZZZ]

save it as Z:\ZZZZ\ZZZ.REG

end

-----------------------------------------

i'll replace XXX and ZZZ.I'm sure this is very easy for all you vbscript programmers.Oh yes,and please make it silent,so i wont have to answer any questions and do not ask if i want to rewrite if file exist.

-one last thing,is it possible in VB to close program? like if i had one script which will close 5 programs which eat resources because and i'm gonna play game(this is only example) so it is possible?

Many Thanks

Dominik

[UserXP]

Here is a VBScript that will do the job

--------------------------------------------

Option Explicit

On Error Resume Next

'Declare variables

Dim WSHShell, TheKey, FName, OkToExec

'Set the Windows Script Host Shell

Set WSHShell = WScript.CreateObject("WScript.Shell")

If (WScript.Arguments.Count > 0) And (WScript.Arguments.Count < 3) Then

OkToExec = True

FName = WScript.Arguments(0)

If WScript.Arguments.Count = 2 Then

TheKey = WScript.Arguments(1)

Else

If MsgBox("Are you sure you want to extract all the registry?", vbYesNo or vbDefaultButton2) = vbNo Then OkToExec = False

End If

'Extract the key from registry

If OkToExec Then

WSHShell.Exec "regedit /e /s """ & FName & """ """ & TheKey & """"

End If

End If

--------------------------------------------

Save it let's say as "c:\ExtractReg.vbs"

After you can run it like this

c:\ExtractReg.vbs X:\XXXX\XXX.REG HKEY_CURRENT_USER\Software\XXXXXXXX

Note: If in any path there is a space you must use the "

Example:

"c:\Program Files\ExtractReg.vbs" "c:\Program Files\test.reg" "HKEY_CURRENT_USER\Software\A Word"

=========================

If you want to have the file name and the key inside the script then use this

--------------------------------------------

Option Explicit

On Error Resume Next

'Declare variables

Dim WSHShell, TheKey, FName

'Set the Windows Script Host Shell

Set WSHShell = WScript.CreateObject("WScript.Shell")

FName = "c:\Program Files\test.reg"

TheKey = "HKEY_CURRENT_USER\Software\A Word"

'Extract the key from registry

WSHShell.Exec "regedit /e /s """ & FName & """ """ & TheKey & """"

--------------------------------------------

[Dominik]

W00T ! You the man! Thanks,works like a charm... I'll need some vbscripting help later with some stuff,i'm sure you'll help me again :yes:

Thanks dude

[UserXP]

Sure, if I can