Script to find the user account

[semaja2.net]

Hi Guys,

I have recently taken over a network where it appears the user folders are never maintained, would someone be able to code a script for me that will list the folders that dont have a user account in AD, and possibly move the folders around according to the OU structure.

[ScottieG]

... oh wow

i'm not sure if this can be done

[fault]

... oh wow

i'm not sure if this can be done

Sure it can :) ... With a bit of work!

I have recently taken over a network where it appears the user folders are never maintained, would someone be able to code a script for me that will list the folders that dont have a user account in AD...

You're in luck as I've just gone through this exercise for our organisation specifically to identify orphaned home directories and how much space they were consuming. You should be able to easily adapt this VB script :) Just change the strHomeDirPath & strDomain variables and run it from a Command Prompt (e.g., cscript myvbscript.vbs)...

' Force explicit variable declaration
Option Explicit

' Required to catch & continue on from errors
On Error Resume Next

' Declare and initialise constants
Const ADS_NAME_INITTYPE_GC = 3
Const ADS_NAME_TYPE_1779 = 1
Const ADS_NAME_TYPE_NT4 = 3

' Declare variables
Dim objFSO, objFolder, objSubFolder, colSubFolders, objNameTranslate, objUser
Dim strDomain, strHomeDirPath, strUserName, strUserNameDN
Dim intFolderSize

' Initialise variables
strHomeDirPath = "D:\Home\"
strDomain = "MYDOMAIN"
Set objNameTranslate = CreateObject("NameTranslate")
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFolder = objFSO.GetFolder(strHomeDirPath)
Set colSubFolders = objFolder.SubFolders

' Output the column headings for our .csv formatted dump
WScript.Echo "Folder Name"& "," & "AD User Name" & "," & "Folder Size" & "," & "Valid/Invalid AD User"

' Loop through all home directories
For Each objSubFolder in colSubFolders
	' Get the folder name (i.e., username)
	strUserName = objSubFolder.Name

	' Translate the username to a distinguished name
	objNameTranslate.Init ADS_NAME_INITTYPE_GC, ""
	objNameTranslate.Set ADS_NAME_TYPE_NT4, strDomain & "\" & strUserName
	strUserNameDN = objNameTranslate.Get(ADS_NAME_TYPE_1779)

	' Get the folder size in megabytes with 1 decimal point
	intFolderSize = Round(objSubFolder.Size / 1024 / 1024, 1)

	' Check if translation failed (i.e., user does not exist in Active Directory)
	If Err.Number <> 0 Then
		' The user no longer exists in Active Directory; don't do anything
		WScript.Echo strUserName & "," & "," & intFolderSize & "," & "invalid"
	Else
		' The user exists in Active Directory; bind to the user using the LDAP provider and get their Display Name
		Set objUser = GetObject("LDAP://" & strUserNameDN)
		WScript.Echo strUserName & "," & objUser.displayName & "," & intFolderSize & "," & "valid"
	End If

	' Clear any errors before looping again
	Err.Clear
Next

' Object destruction
Set objFSO = Nothing
Set colSubFolders = Nothing
Set objFolder = Nothing
Set objSubFolder = Nothing
Set objNameTranslate = Nothing
Set objUser = Nothing

' Quit
WScript.Quit

That'll give you a comma separated file which you can import into Excel (or Numbers if you're a Mac fan given your signature? :p) if you need to produce a report/manipulate the data further - or you could directly send the output to a file to make it easier to work with immediately e.g., cscript myvbscript.vbs > myoutputfile.csv. If you're wanting to move/delete the orphaned home directories right away, just add the required code into the Else branch of the If/Else statement.

As for the second part of your request...

... possibly move the folders around according to the OU structure

I'm not entirely sure what you want to do here. Are you asking whether you can use a script to move a user's home directory to another folder based on the user's Organisational Unit? Or...?

Edited September 8, 2008 by fault