Backup for NT Server

[LittleNeutrino Veteran]

I am attempting to setup NAS backup for NT Server I have mapped my NAS as a drive however the windows backup utility will only back up the data to a Tape Drive or Physical drive but not to a network drive is there any software that i can install on it that would allow me to do this. I have tried Memeo and Cobian Backup however neither of them support Windows NT

[Joel]

Does your NAS go home with you at night? Or is it offsite?

[thefarewellnote]

I have used this post I found over at another forum for some of our clients and it worked well. Not sure of your network setup but this should work.

What I've always done in the past is used a batchfile to:

a) map a network drive

b) perform the backup

c) copy the backup file (using xcopy) to the network drive.

Here's a quick example of the batchfile:

***Begin Batchfile***

@echo off
rem clear mapped network drives
net use * /d /y

rem map network drive to backup folder on server
net use m: \\pcname\sharedfolder /persistent:yes
rem perform the backup
C:\WINDOWS\system32\ntbackup.exe backup "@C:\Documents and Settings\username\Local Settings\Application Data\Microsoft\Windows NT\NTBackup\data\Daily Backup.bks" /n "Daily Backup.bkf created 3/25/2004 at 9:27 PM" /d "Set created 3/25/2004 at 9:27 PM" /v:yes /r:yes /rs:no /hc:off /m normal /j "Daily Backup" /l:s /f "F:\Backup\Daily Backup.bkf"
rem copy the backup to the server
xcopy f:\backup\"daily backup.bkf" m:\ /y
rem release mapped drive
net use * /d /y
rem exit the batch file
exit
***End Batchfile***

First, the batchfile clears mapped drives. In my case, this is a batchfile I use on my systems at home to back them all up to one PC. So, since I don't have a pile of mapped drives, I just make sure all mapped drives are diconnected (net use * /d /y). When I've used this in a work environment with multiple mapped drives, I disconnected only the one drive I map to the main backup folder.

The next thing is map the drive (in the case of this batchfile, I used m:.

Then the backup operation itself. To get the command line, created a scheduled backup task using ntbackup. Once you're finished, open the scheduled task and copy the command line for the backup out of it and paste it in your batchfile.

Then the xcopy operation which moves the file to your central backup folder.

Then finally, disconnect the mapped drive.

Once you've tailored this to your environment, (paths, server names, shares, etc) test it. Make sure it works. Once it's working properly, make a scheduled task that calls the batchfile.

A word of advice. Since you have multiple servers, stagger the timing of the backups on them so as not to overload the target server with 10 or 11 backups being copied to it at one time.

Then, schedule your backup on the backup server for after all files are copied.

I've used this exact method many times in business and it's always worked well.

One last thing. It seems tedious to always disconnect the drive within the batchfile but trust me on this ok, you want to. Windows has a bad habit of losing mappings. The only way I found to ensure the backups always run and copy properly across the network was to ensure the drive was freshly mapped.

Don't forget, check your backups EVERY morning to ensure they've all run properly over night. This should be almost the first thing any system admin does every morning.

[LittleNeutrino Veteran]

the NAS is in another building however still on our site here at the company.