Batch strip metadata from files

[Jon 5]

I need a program (free or paid) that will strip the metadata from Microsoft Office documents (Excel, Word, Powerpoint) and Adobe PDF's.

I found BatchPurifier, but it does not do it for Microsoft Office 2003 documents.

I have hundreds of documents that I need scrubbed so individually doing it is not a viable option.

Any suggestions? Thanks

[+BudMan MVC]

Here is the tool from MS for doing it

http://www.microsoft.com/downloads/details.aspx?familyid=144e54ed-d43e-42ca-bc7b-5446d34e5360&displaylang=en

Office 2003/XP Add-in: Remove Hidden Data

Brief Description

With this add-in you can permanently remove hidden data and collaboration data, such as change tracking and comments, from Microsoft Word, Microsoft Excel, and Microsoft PowerPoint files.

You can run the Remove Hidden Data add-in on individual files from within your Office XP or Office 2003 application. Or, you can run Remove Hidden Data on multiple files at once from the command line. In either case, to run the tool you must have the application installed in which the document was created.

[Jon 5]

Thanks for responding. I had already tried that, but it wanted Office 2003 and I am using 2010. Also, it would only handle 2003 stuff from what I can tell.

I finally found/finagled a free solution. It is based off this. This will strip/scrub metadata from most types of files (except zips/archives).

I changed some things and wrote a readme. You will need dsofile.dll which can be found here from Microsoft.

  Quote

This script will remove metadata/properties from files in a folder and all sub-folders.

More specifically this will clear the following fields of metadata: Author, Category, Comments, Company, Keywords, LastSavedBy, Manager, Subject and Title.

You must run this program on an x86 machine, or it will throw an error.

1st - Copy dsofile.dll to C:\Windows\System32

2nd - Start, run, cmd. Run the command "regsvr32 C:\Windows\System32\dsofile.dll"

3rd - Place scrub.vbs in the folder that contains the files you want to scrub.

4th - Double click on scrub.vbs. If you do not see a message saying everthing went okay within a few minutes, then run this vbs file from the command line to check for errors.

Option Explicit

Dim objFSO 'module Level Object
Dim objDSOFile 'module Level Object

call Main

sub Main
	Dim objFolder
	Set objFSO = CreateObject("Scripting.FileSystemObject")
	Set objDSOFile = CreateObject("DSOFile.OleDocumentProperties")
	Set objFolder = objFSO.GetFolder(".")

	call ProcessFolder(objFolder)

	Set objFSO = nothing
	Set objDSOFile = nothing

end sub

Sub ProcessFolder(objFolder)
	dim objFiles,objFile
	dim objSubFolders,objSubFolder

	Set objFiles = objFolder.Files

	For Each objFile In objFiles
		if lcase(objFSO.getExtensionname(objFile)) <> "zip" then
			call OverWriteFile(objFile)
		end if
	Next

	Set objSubFolders = objFolder.SubFolders

	For Each objSubFolder in ObjSubFolders
		call ProcessFolder(objSubFolder)
	Next

end Sub

Sub OverWriteFile(objFile)
    objDSOFile.Open(objFile.Path)
    objDSOFile.SummaryProperties.Author = " "
    objDSOFile.SummaryProperties.Category = " "
    objDSOFile.SummaryProperties.Comments = " "
    objDSOFile.SummaryProperties.Company = " "
    objDSOFile.SummaryProperties.Keywords = " "
    objDSOFile.SummaryProperties.LastSavedBy = " "
    objDSOFile.SummaryProperties.Manager = " "
    objDSOFile.SummaryProperties.Subject = " "
    objDSOFile.SummaryProperties.Title = " "
    objDSOFile.Save
    objDSOFile.Close
end sub

msgbox "Everything completed successfully. Please verify files."

Wscript.quit